'e-mail: Wolf.W.Radzinski@onlinehome.de
'Benutzung frei - ohne Gewähr


Function QuickSortArray(varArray As Variant, _
                        Optional lngFirst As Long = -1, _
                        Optional lngLast As Long = -1) As Variant

    ' Zum Sortieren der Elemente im varArray-Array
    ' verwendeter QuickSort-Algorithmus.

    Dim lngLow      As Long
    Dim lngHigh     As Long
    Dim lngMiddle   As Long
    Dim varTempVal  As Variant
    Dim varTestVal  As Variant

    If lngFirst = -1 Then lngFirst = LBound(varArray)
    If lngLast = -1 Then lngLast = UBound(varArray)

    If lngFirst < lngLast Then
        lngMiddle = (lngFirst + lngLast) / 2
        varTestVal = varArray(lngMiddle)
        lngLow = lngFirst
        lngHigh = lngLast
        Do
            Do While varArray(lngLow) < varTestVal
                lngLow = lngLow + 1
            Loop
            Do While varArray(lngHigh) > varTestVal
                lngHigh = lngHigh - 1
            Loop
            If (lngLow <= lngHigh) Then
                varTempVal = varArray(lngLow)
                varArray(lngLow) = varArray(lngHigh)
                varArray(lngHigh) = varTempVal
                lngLow = lngLow + 1
                lngHigh = lngHigh - 1
            End If
        Loop While (lngLow <= lngHigh)
        If lngFirst < lngHigh Then QuickSortArray varArray, lngFirst, lngHigh
        If lngLow < lngLast Then QuickSortArray varArray, lngLow, lngLast
    End If
End Function